Try OpenEdge Now
skip to main content
ABL Reference
ABL Syntax Reference : CREATE automation object statement
 

CREATE automation object statement

(Windows only)
Creates (instantiates) an ActiveX Automation object based on a specified Automation Server connection.

Syntax

CREATE expression1COM-hdl-var
[ CONNECT [ TO expression2 ] ]
[ NO-ERROR ]
expression1
A character-string expression that evaluates to 1) a unique name of a valid Automation object stored in the system registry or 2) the null string ("").
COM-hdl-var
A COM-HANDLE variable that receives the COM handle to the instantiated Automation object.
[CONNECT [ TO expression2] ]
Specifies the connection option, together with expression1. The behavior of each connection option depends on the execution status of the Automation Server. The following table illustrates this behavior.
Table 20. Automation object connection options
Connection option
Server execution status
Connection behavior
1. Option omitted
Running
Creates a new instance of the Automation object identified by expression1. Launches a new instance of the Server for top-level Automation objects (like Excel.Application).
Not running
Launches a new instance of the Server, then creates a new instance of the Automation object identified by expression1. Often, both the new Server and the new Automation object instance are invisibly created.
2. CONNECT
Running
Connects to an active (instantiated) Automation object identified by expression1. Works for top-level Automation objects only. For example, this works for Excel.Application but fails for Excel.Sheet and Excel.Chart, which are both lower-level Automation objects.
Not running
Invalid. Always returns an error.
3. CONNECT TO expression2
Running
Creates or connects to an Automation object specified by expression1 that is associated with the file specified by the pathname in expression2. If more than one instance of the Server is running, this option randomly selects one (generally, the first one started). If the specified file is already open within the selected Server, this option connects to the Automation object that is instantiated for that file. If the file is not already open in the selected Server, this option opens the file and instantiates the specified Automation object for it.
If the specified file is already open in a different instance of the Server, this option fails with a "File in Use" error. This option also fails if the expression2 does not specify a valid file.
Not running
Creates a new instance of an Automation object specified by expression1 that is associated with the file specified by the pathname in expression2. This option starts a new instance of the Server and instantiates the Automation object for the class that is initialized from the contents of the file. Often, the new Server, as well as the new Automation object, are invisibly created.
This option fails if expression2 does not specify a valid file.
4. CONNECT TO expression2 WHERE expression1 = ""
Running
Creates or connects to an Automation object that is associated with the file specified by the pathname in expression2. This option determines the identity of the Server (and hence the Automation object) from the file extension given in expression2. If more than one instance of the Server is running, this option randomly selects one (generally, the first one started). If the specified file is already open within the selected Server, this option connects to the Automation object that is instantiated for that file. If the file is not already open in the selected Server, this option opens the file and instantiates the specified Automation object for it.
If the specified file is already open in a different instance of the Server, this option fails with a "File in Use" error. This option also fails if the expression2 does not specify a valid file.
Not running
Creates a new instance of an Automation object that is associated with the file specified by the pathname in expression2. This option determines the identity of the Server (and hence the Automation object) from the file extension given in expression2. This option starts a new instance of the Server and instantiates the Automation object for the class that is initialized from the contents of the file. Often, the new Server, as well as the new Automation object, are invisibly created.
This option fails if expression2 does not specify a valid file.
NO-ERROR
Suppresses ABL errors or error messages that would otherwise occur and diverts them to the ERROR-STATUS system handle. If an error occurs, the action of the statement is not done and execution continues with the next statement. If the statement fails, any persistent side-effects of the statement are backed out. If the statement includes an expression that contains other executable elements, like methods, the work performed by these elements may or may not be done, depending on the order the AVM resolves the expression elements and the occurrence of the error.
To check for errors after a statement that uses the NO-ERROR option:
*Check the ERROR-STATUS:ERROR attribute to see if the AVM raised the ERROR condition.
*Check if the ERROR-STATUS:NUM-MESSAGES attribute is greater than zero to see if the AVM generated error messages. ABL handle methods used in a block without a CATCH end block treat errors as warnings and do not raise ERROR, do not set the ERROR-STATUS:ERROR attribute, but do add messages to the ERROR-STATUS system handle. Therefore, this test is the better test for code using handle methods without CATCH end blocks. ABL handle methods used in a block with a CATCH end block raise ERROR and add messages to the error object generated by the AVM. In this case, the AVM does not update the ERROR-STATUS system handle.
*Use ERROR-STATUS:GET-MESSAGE( message-num ) to retrieve a particular message, where message-num is 1 for the first message.
If the statement does not include the NO-ERROR option, you can use a CATCH end block to handle errors raised by the statement.
Some other important usage notes on the NO-ERROR option:
*NO-ERROR does not suppress errors that raise the STOP or QUIT condition.
*A CATCH statement, which introduces a CATCH end block, is analogous to a NO-ERROR option in that it also suppresses errors, but it does so for an entire block of code. It is different in that the error messages are contained in a class-based error object (generated by the AVM or explicitly thrown), as opposed to the ERROR-STATUS system handle. Also, if errors raised in the block are not handled by a compatible CATCH block, ON ERROR phrase, or UNDO statement, then the error is not suppressed, but handled with the default error processing for that block type.
*When a statement contains the NO-ERROR option and resides in a block with a CATCH end block, the NO-ERROR option takes precedence over the CATCH block. That is, an error raised on the statement with the NO-ERROR option will not be handled by a compatible CATCH end block. The error is redirected to the ERROR-STATUS system handle as normal.
*If an error object is thrown to a statement that includes the NO-ERROR option, then the information and messages in the error object will be used to set the ERROR-STATUS system handle. This interoperability feature is important for those integrating code that uses the traditional NO-ERROR technique with the newer, structured error handling that features error objects and CATCH end blocks.

Example

The following procedure demonstrates several Automation object instantiations using the four basic connection options. It tries all of the options with the Microsoft® Excel Automation Server. Note that not all Automation Servers support all options. For example in Office 95, there is no Automation object for PowerPoint presentations. Thus, the file connection option (Option 3 in Table 20) does not work.
r-crea.p
/* Demonstration of connecting to an Automation Object in Excel using the
   different connection options. */

DEFINE VARIABLE curDir   AS CHARACTER  NO-UNDO.
DEFINE VARIABLE cEditor  AS CHARACTER  NO-UNDO
  VIEW-AS EDITOR SIZE 63 BY 1 LABEL "Result:" FONT 2.
DEFINE VARIABLE wordAppl AS COM-HANDLE NO-UNDO.

DEFINE BUTTON bExit
  LABEL "Exit" SIZE 16 BY 1.25 AUTO-GO.
DEFINE BUTTON bStart
  LABEL "Option 1 - Start Excel" SIZE 32 BY 1.25 .
DEFINE BUTTON bConnect
  LABEL "Option 2 - Connect to Active" SIZE 32 BY 1.25.
DEFINE BUTTON bConPerFile
  LABEL "Option 3 - Connect per File" SIZE 32 BY 1.25.
DEFINE BUTTON bConnectMon
  LABEL "Option 4 - Connect by Extension" SIZE 32 BY 1.25.

ASSIGN
  FILE-INFO:FILE-NAME = "."
  curDir              = FILE-INFO:FULL-PATHNAME.

FORM cEditor SKIP(0.5) bStart SPACE bConnect SPACE bConPerFile SPACE
  bConnectMon SKIP(0.5) bExit
  WITH FRAME a VIEW-AS DIALOG-BOX THREE-D FONT 6.
FRAME a:TITLE = "Testing CREATE Automation Object Statement".

ENABLE ALL WITH FRAME a.

ON CHOOSE OF bStart IN FRAME a DO:
  /* Option 1: CREATE expression1 Com-Handle-Var. */
  DEFINE VARIABLE excelAppl AS COM-HANDLE NO-UNDO.

  CREATE "Excel.Application" excelAppl.
  excelAppl:Visible = TRUE.
  excelAppl:Workbooks:Add.
  excelAppl:Range("A1"):Value = "testing CREATE".
  ASSIGN cEditor:SCREEN-VALUE = STRING(excelAppl:Range("A1"):Value).
  RELEASE OBJECT excelAppl.
END.

ON CHOOSE OF bConnect IN FRAME a DO:
/* Option 2: CREATE expression1 Com-Handle-Var CONNECT. */
  DEFINE VARIABLE excelAppl AS COM-HANDLE NO-UNDO.

  CREATE "Excel.Application" excelAppl CONNECT.
excelAppl:Range("A2"):Value = "testing CONNECT".
MESSAGE "Click me to continue!" VIEW-AS ALERT-BOX.
ASSIGN cEditor:SCREEN-VALUE = STRING(excelAppl:Range("A2"):Value).
excelAppl:Workbooks:Item(1):SaveAs(curDir + "\yyy.xls").
excelAppl:Quit().
RELEASE OBJECT excelAppl.
END.

ON CHOOSE OF bConPerFile IN FRAME a DO:
/* Option 3: CREATE expression1 Com-Handle-Var CONNECT TO expression2. */
  DEFINE VARIABLE excelAppl AS COM-HANDLE NO-UNDO.
  DEFINE VARIABLE cFileName AS CHARACTER  NO-UNDO
    INITIAL "\WorkSheets\Xplan.xls".

CREATE "Excel.Sheet" excelAppl CONNECT TO cFileName.
excelAppl:Visible = TRUE.
excelAppl:Workbooks:Add.
excelAppl:Range("A3"):Value = "testing CONNECT TO".
ASSIGN cEditor:SCREEN-VALUE = STRING(excelAppl:Range("A3"):Value).
  RELEASE OBJECT excelAppl.
END.

ON CHOOSE OF bConnectMon IN FRAME a DO:
/* Option 4: CREATE "" Com-Handle-Var CONNECT TO expression2. */
  DEFINE VARIABLE excelAppl AS COM-HANDLE NO-UNDO.
  DEFINE VARIABLE cFileName AS CHARACTER  NO-UNDO
    INITIAL "\WorkSheets\Xplan.xls".

  CREATE "" excelAppl CONNECT TO cFileName.
excelAppl:Range("A4"):Value = "testing CONNECT TO where expression1 = ''".
MESSAGE "Click me to continue!" VIEW-AS ALERT-BOX.
ASSIGN cEditor:SCREEN-VALUE = STRING(excelAppl:Range("A4"):Value).
excelAppl:Workbooks:Item(1):SaveAs(curDir + "\zzz.xls").
excelAppl:Quit().
  RELEASE OBJECT excelAppl.
END.

Notes

*You must ensure that any third-party Automation objects you want to instantiate are installed and correctly listed in the registry. For information on what Automation objects you can instantiate, see the documentation for the third-party product. Generally, these are the same Automation objects instantiated by the Visual Basic CreateObject and GetObject functions. You might also be able to view these Automation objects using the OpenEdge COM Object Viewer tool. For more information, see OpenEdge Development: Programming Interfaces.
*The instantiation of an Automation object depends on the implementation of the Automation Server itself. Any Server registered for multiple use (REGCLS_MULTIPLE_USE flag) launches a single instance of the Server that handles multiple Automation object instantiation requests. Any Server registered single use (REGCLS_SINGLE_USE flag) launches a new instance of the Server for each instantiated Automation object.
*The four connection options in Table 20 compare to the following Visual Basic function calls:
*Option 1 — CreateObject (class) or GetObject ("", class)
*Option 2 — GetObject (, class)
*Option 3 — GetObject (pathname, class)
*Option 4 — GetObject (pathname)
*Once you create or connect to an Automation object, you can reference its properties and methods.

See also

RELEASE OBJECT statement