Release 10.1A: OpenEdge Development:
Progress 4GL Reference

> ## STATUS statement

> Specifies the text that appears in the status line of a window. Progress displays the following default messages on that line:

> - When a procedure is blocked and is waiting for the user to enter data into a frame field, the status message is “Enter data or press `end-error` to end,” where `end-error` is the key label for the END-ERROR key.

> - When a procedure reaches a PAUSE statement, the status message is “Press space bar to continue.”

> - While procedure is not blocked for input, the status message blank.

> Note: Does not apply to SpeedScript programming.

> #### Syntax

>     STATUS
>       {   DEFAULT [ expression ]
>         | INPUT [ OFF | expression ]
>       }
>       [ IN WINDOW window ]

> `DEFAULT `expression``

> Replaces the default status message when a user is running a procedure (the default status message is blanks). The `expression` must be character and must be enclosed in quotes if it is a constant. If you do not specify an `expression`, Progress resets the STATUS DEFAULT line to its original state. The STATUS DEFAULT is a maximum of 63 characters.

> `INPUT OFF`

> Tells Progress not to display an input status message.

> `INPUT `expression``

> Replaces the default status message when a user is entering data into a frame field. The `expression` must be character and must be enclosed in quotes if it is a constant. If you do not specify an `expression`, Progress resets the STATUS INPUT line to its original state.

> `IN WINDOW `window``

> Specifies the window in which to set the status message. If you omit the IN WINDOW phrase, the STATUS statement applies to the current window.

> Example

> This procedure replaces the default status messages with two other messages:

> r-status.p
>     STATUS DEFAULT "All Around Sports Order Processing System".
>     STATUS INPUT "Enter data, or use the " + KBLABEL("END-ERROR") +
>       " key to exit".
>     FOR EACH customer:
>       DISPLAY name.
>       FOR EACH order OF customer:
>         UPDATE order-num promise-date order-date ship-date.
>       END.
>       UPDATE credit-limit.
>     END.

> #### Notes

> - After you use the STATUS DEFAULT, STATUS INPUT OFF, or STATUS INPUT statement during a session, that statement is in effect for all the procedures run in that session, unless it is overridden by other STATUS statements in those procedures, or until you return to the Procedure Editor.

> - You cannot use the STATUS statement to change the default status messages displayed while you are in the Procedure Editor.

> - You can use the PAUSE statement to override the default status message displayed when Progress encounters a PAUSE statement.

> - When you use the HELP attribute to display help text for a widget, Progress overwrites the status text with the HELP text.

> #### See also

> MESSAGE statement, PAUSE statement

Copyright © 2005 Progress Software Corporation www.progress.com Voice: (781) 280-4000 Fax: (781) 280-4095