Release 10.1A: OpenEdge Development:
Progress 4GL Reference

> ## RUN SUPER statement

> Runs the super procedure version of the current internal procedure.

> The RUN SUPER statement must appear only within an internal procedure, but can appear anywhere within the internal procedure. If the RUN SUPER statement appears outside an internal procedure, the compiler reports an error.

> #### Syntax

>     RUN SUPER [ ( parameter [ , parameter ] ... ) ] [ NO-ERROR ]

> ``parameter``

> A parameter of the super procedure. The parameters of the super procedure must have the same `signature` (number of parameters, and type and mode of each) as the parameters of the current internal procedure. You can, however, adjust a parameter’s value.

> For the `parameter` syntax, see the Parameter passing syntax reference entry in this book.

> `NO-ERROR`

> Suppresses the display of the error message if the search for the super procedure version of the current internal procedure fails. The error is still generated and stored in the ERROR-STATUS handle.

> Note: Specifying NO-ERROR does not shorten the search in any way.

> If you do not specify the NO-ERROR option and the super procedure version of the internal procedure does not exist, Progress generates an error message:

>     Procedure prog.p name has no SUPER procedure with internal procedure name

> Example

> The following example consists of three procedure files: a main routine, a driver, and a third procedure file that becomes a super procedure of the driver.

> The following main routine, procedure file `r-pomain.p`, runs the driver procedure persistently:

> r-pomain.p
>     /* r-pomain.p */
>     DEFINE VARIABLE h AS HANDLE.
>     DEFINE VARIABLE a AS CHARACTER.
>     FUNCTION sample2 RETURNS CHARACTER (INPUT-OUTPUT a AS CHARACTER) IN h.

>     RUN r-podrvr.p PERSISTENT SET h.
>     RUN sample1 IN h (INPUT-OUTPUT a).
>     MESSAGE a VIEW-AS ALERT-BOX.
>     a = "".
>     MESSAGE sample2(a) VIEW-AS ALERT-BOX.

> The following driver, procedure file `r-podrvr.p`, runs the third procedure file persistently, makes it a super procedure of itself, defines the internal procedure sample1, and defines the user-defined functions sample2, GetPartName, and SetPartName:

> r-podrvr.p
>     /* r-podrvr.p */
>     FUNCTION SetPartName RETURNS INTEGER (INPUT a AS CHARACTER) FORWARD.
>     DEFINE VARIABLE h AS HANDLE.DEFINE VARIABLE localPartName AS CHARACTER.

>     /* Add a super procedure */
>     RUN r-posupr.p PERSISTENT SET h.
>     THIS-PROCEDURE:ADD-SUPER-PROCEDURE (h).
>     SetPartName("1998 Calendar").

>     PROCEDURE sample1:
>         DEFINE INPUT-OUTPUT PARAMETER a AS CHARACTER.
>         a = a + "proc: Part name is: ".
>         /* Invoke procedure sample1 in the super procedure. */
>         RUN SUPER (INPUT-OUTPUT a).
>     END PROCEDURE.
>     FUNCTION sample2 RETURNS CHARACTER (INPUT-OUTPUT a AS CHARACTER).
>         a = a + "func: Part name is: ".
>         /* Invoke function sample2 in the super procedure. */
>         SUPER (INPUT-OUTPUT a).
>         RETURN a.
>     END FUNCTION.
>     FUNCTION GetPartName RETURNS CHARACTER ():
>         RETURN localPartName.
>     END FUNCTION.
>     FUNCTION SetPartName RETURNS INTEGER (INPUT partname AS CHARACTER):
>         localPartName = partname.
>     END FUNCTION.

> The following third procedure file, `r-posupr.p`, defines a new version of the internal procedure sample1 and a new version of the user-defined function sample2:

> r-posupr.p
>     /* r-posupr.p */
>     DEFINE VARIABLE h AS HANDLE.
>     FUNCTION GetPartName RETURNS CHARACTER () IN H.

>     PROCEDURE sample1:
>         DEFINE INPUT-OUTPUT PARAMETER a AS CHARACTER.
>         h = TARGET-PROCEDURE.
>         a = a + GetPartName().
>         MESSAGE "TARGET-PROCEDURE is:" TARGET-PROCEDURE:FILE-NAME
>             VIEW-AS ALERT-BOX.
>         MESSAGE "SOURCE-PROCEDURE is:" SOURCE-PROCEDURE:FILE-NAME
>             VIEW-AS ALERT-BOX.
>     END PROCEDURE.

>     FUNCTION SAMPLE2 RETURNS CHARACTER (INPUT-OUTPUT a AS CHARACTER):
>         h = TARGET-PROCEDURE.
>         a = a + GetPartName().
>         RETURN a.
>     END.

> To start the example, run `r-pomain.p` from the Procedure Editor.

> #### Notes

> - To run the super version of a user-defined function, use the SUPER function.

> - For the rules that Progress uses to find the super procedure, see the reference entry for the ADD-SUPER-PROCEDURE( ) method in this book.

> - For an overview of super procedures, see OpenEdge Development: Progress 4GL Handbook .

> #### See also

> ADD-SUPER-PROCEDURE( ) method, REMOVE-SUPER-PROCEDURE( ) method, SOURCE-PROCEDURE system handle, SUPER function, SUPER-PROCEDURES attribute, TARGET-PROCEDURE system handle

Copyright © 2005 Progress Software Corporation www.progress.com Voice: (781) 280-4000 Fax: (781) 280-4095