Release 10.1A: OpenEdge Data Management:
SQL Reference

> ## Search conditions syntax in BNF

> ## Search condition

> #### Syntax

>     search_condition ::=
>     [ NOT ] predicate
>       [ { AND | OR } { predicate | ( search_condition ) } ]

> ##### Predicate

> Syntax
>     predicate ::=
>     basic_predicate
>       | quantified_predicate
>       | between_predicate
>       | null_predicate
>       | like_predicate
>       | exists_predicate
>       | in_predicate
>       | outer_join_predicate

> ##### Relational operator

> Syntax
>     relop ::=
>     =  | <> | != | ^= | < | <= | > | >=

> ##### Basic predicate

> Syntax
>     basic_predicate ::=
>     expr relop { expr | ( query_expression ) }

> ##### Quantified predicate

> Syntax
>     quantified_predicate ::=
>     expr relop { ALL | ANY | SOME } ( query_expression )

> ##### Between predicate

> Syntax
>     between_predicate ::=
>     expr [ NOT ] BETWEEN expr AND expr

> ##### Null predicate

> Syntax
>     null_predicate ::=
>     column_name IS [ NOT ] NULL

> ##### Like predicate

> Syntax
>     like_predicate ::=
>     column_name [ NOT ] LIKE string_constant
>       [ ESCAPE escape_character ]

> ##### Exists predicate

> Syntax
>     exists_predicate ::=
>     EXISTS (query_expression)

> ##### In predicate

> Syntax
>     in_predicate ::=
>     expr [ NOT ] IN
>       { (query_expression) | (constant , constant [ , ... ] ) }

> ##### Outer join predicate

> Syntax
>     outer_join_predicate ::=
>     [ table_name.]column = [ table_name.]column (+)
>       | [ table_name.]column (+) = [ table_name.]column

Copyright © 2005 Progress Software Corporation www.progress.com Voice: (781) 280-4000 Fax: (781) 280-4095