(Windows only)
Specifies
environment defaults that apply to subsequent windows that the application
creates. The defaults might reside in the registry or in an initialization
file. The defaults can involve colors, fonts, environment variables,
etc. You must specify a default in a LOAD statement before you specify
it in a USE statement.
Note: Does not apply to
SpeedScript programming.
Syntax
USE environment [ NO-ERROR ]
|
-
environment
-
A CHARACTER expression that evaluates to the name of a current
environment. If environment is non-null, it must
have appeared in a prior LOAD statement. If environment is
the null string (""), the default environment becomes the current
environment.
- NO-ERROR
-
Suppresses ABL errors or error messages that would otherwise occur
and diverts them to the ERROR-STATUS system handle. If an error occurs, the action of the statement
is not done and execution continues with the next statement. If
the statement fails, any persistent side-effects of the statement
are backed out. If the statement includes an expression that contains
other executable elements, like methods, the work performed by these
elements may or may not be done, depending on the order the AVM
resolves the expression elements and the occurrence of the error.
To
check for errors after a statement that uses the NO-ERROR option:
- Check the ERROR-STATUS:ERROR attribute to see if the AVM raised
the ERROR condition.
- Check if the ERROR-STATUS:NUM-MESSAGES attribute is greater than
zero to see if the AVM generated error messages. ABL handle methods
used in a block without a CATCH end block treat errors as
warnings and do not raise ERROR, do not set the ERROR-STATUS:ERROR
attribute, but do add messages to the ERROR-STATUS system handle.
Therefore, this test is the better test for code using handle methods
without CATCH end blocks. ABL handle methods used in a block with a
CATCH end block raise ERROR and add messages to the error object
generated by the AVM. In this case, the AVM does not update the
ERROR-STATUS system handle.
- Use ERROR-STATUS:GET-MESSAGE( message-num )
to retrieve a particular message, where message-num is
1 for the first message.
If the statement does not include
the NO-ERROR option, you can use a CATCH end block to handle errors
raised by the statement.
Some other important usage notes
on the NO-ERROR option:
- NO-ERROR does not suppress errors
that raise the STOP or QUIT condition.
- A CATCH statement, which introduces a CATCH end block, is analogous
to a NO-ERROR option in that it also suppresses errors, but it does so
for an entire block of code. It is different in that the error messages
are contained in a class-based error object (generated by the AVM
or explicitly thrown), as opposed to the ERROR-STATUS system handle.
Also, if errors raised in the block are not handled by a compatible
CATCH block, ON ERROR phrase, or UNDO statement, then the error
is not suppressed, but handled with the default error processing
for that block type.
- When a statement contains the NO-ERROR option and resides in
a block with a CATCH end block, the NO-ERROR option takes precedence over
the CATCH block. That is, an error raised on the statement with
the NO-ERROR option will not be handled by a compatible CATCH end block.
The error is redirected to the ERROR-STATUS system handle as normal.
- If an error object is thrown to a statement that includes the NO-ERROR
option, then the information and messages in the error object will
be used to set the ERROR-STATUS system handle. This interoperability
feature is important for those integrating code that uses the traditional
NO-ERROR technique with the newer, structured error handling that
features error objects and CATCH end blocks.
Example
This
procedure loads two files, env1.ini and env2.ini, each of which contains
a font definition for font0. The program displays a character string
in the ABL default window using the definition for font0 from env1.ini.
It then creates a new window and displays the same character string
using the definition for font0 from env2.ini. Note that the procedure
creates the window after the USE statement.
r-use.p
DEFINE VARIABLE w1 AS CHARACTER NO-UNDO VIEW-AS TEXT FONT 0
FORMAT "x(34)" INITIAL "This is font 0 in the first window".
DEFINE VARIABLE w2 AS CHARACTER NO-UNDO VIEW-AS TEXT FONT 0
FORMAT "x(35)" INITIAL "This is font 0 in the second window".
DEFINE VARIABLE new_win AS HANDLE NO-UNDO.
LOAD "env1".
LOAD "env2".
USE "env1".
DISPLAY w1 WITH NO-LABELS WITH FRAME a.
PAUSE.
USE "env2".
CREATE WINDOW new_win.
CURRENT-WINDOW = new_win.
DISPLAY w2 in WINDOW new_win WITH NO-LABELS WITH FRAME b.
PAUSE.
DELETE WIDGET new_win.
|
This procedure depends on the existence of files
named env1.ini and env2.ini, each of which contains a font definition
for font0. If you run this procedure in your environment, you must
create these files.
Notes
- The USE statement does not change the DefaultFont or the DefaultFixedFont settings. It
uses only the information in the [fonts] and [colors] sections of the new current
environment's initialization file.
- Use this statement with applications (such as the AppBuilder)
that build and run other applications using a unique set of environment
specifications.
- An application must use this statement after the LOAD statement
and before a new window is created to make the loaded set of environment specifications
apply to the new window.
- Subsequent PUT-KEY-VALUE and GET-KEY-VALUE statements apply
to the environment made available by the USE statement.
