Try OpenEdge Now
skip to main content
ABL Reference
ABL Syntax Reference : RIGHT-TRIM function
 

RIGHT-TRIM function

Removes trailing white space, or other specified characters, from a CHARACTER or LONGCHAR expression. The data type of the returned value matches the data type of the expression passed to the function.

Syntax

RIGHT-TRIM ( expression[ , trim-chars] )
expression
An expression (a constant, field name, variable name, or expression) whose value is a CHARACTER or LONGCHAR. If expression is a case-sensitive variable, the AVM performs a case-sensitive trim. If expression is a LONGCHAR, the result is in the same code page.
trim-chars
A character expression that specifies the characters to trim from expression. If you do not specify trim-chars, the RIGHT-TRIM function removes spaces, tabs, line feeds, and carriage returns.

Example

The following example shows the effects of the TRIM, RIGHT-TRIM, and LEFT-TRIM functions:
r-ltrim.p
DEFINE VARIABLE ix  AS INTEGER   NO-UNDO.
DEFINE VARIABLE txt AS CHARACTER NO-UNDO FORMAT "X(26)"
  INITIAL "***** This is a test *****".

DEFINE BUTTON b_left  LABEL "Left Trim".
DEFINE BUTTON b_right LABEL "Right Trim".
DEFINE BUTTON b_trim LABEL "Trim".
DEFINE BUTTON b_quit LABEL "Quit" AUTO-ENDKEY.

DEFINE FRAME butt-frame
txt ix LABEL "String Length" SKIP(2)
b_left b_right b_trim b_quit
WITH CENTERED TITLE "Original Text String".

DEFINE FRAME trimed-frame
txt LABEL "Trimed Text"
ix  LABEL "Length"
  WITH CENTERED.

ON CHOOSE OF b_trim, b_right, b_left IN FRAME butt-frame DO:
FRAME trimed-frame:TITLE = "Data After " + SELF:LABEL.
DISPLAY TRIM(txt, "* ") WHEN SELF:LABEL = "Trim" @ txt
LENGTH(TRIM(txt, "* ")) WHEN SELF:LABEL = "Trim" @ ix
LEFT-TRIM(txt,"* ") WHEN SELF:LABEL = "Left Trim" @ txt
LENGTH(LEFT-TRIM(txt,"* ")) WHEN SELF:LABEL = "Left Trim" @ ix
RIGHT-TRIM(txt, "* ") WHEN SELF:LABEL = "Right Trim" @ txt
LENGTH(RIGHT-TRIM(txt, "* ")) WHEN SELF:LABEL = "Right Trim" @ ix
WITH FRAME trimed-frame.
END.

ENABLE b_left b_right b_trim b_quit WITH FRAME butt-frame.

ix = LENGTH(txt).
DISPLAY txt ix WITH FRAME butt-frame.

WAIT-FOR CHOOSE OF b_quit IN FRAME butt-frame.

Notes

*The RIGHT-TRIM function is similar to the TRIM function except that it trims characters only from the right end of the string.
*If expression is a case-sensitive field or variable, then trim-chars is also treated as case sensitive. Otherwise, trim-chars is not case sensitive.
*The RIGHT-TRIM function is double-byte enabled. The specified expression and trim-chars arguments can contain double-byte characters. RIGHT-TRIM does not remove double-byte space characters by default.

See also

LEFT-TRIM function, TRIM function